Ticket #1536: process.d

/**
 * Copyright: Copyright (c) 2009 Jacob Carlborg. All rights reserved.
 * Authors: Jacob Carlborg
 * Version: Initial created: Mar 17, 2009
 *          Feb 20, 2010: Removed dependency on Carbon
 * 
 * License: BSD style: $(LICENSE)
 */ 
module process;

version (darwin)
{
    import tango.stdc.posix.stdlib : realpath;
    import tango.stdc.stringz : strlenz;
    private extern (C) int _NSGetExecutablePath(char* buf, uint* bufsize);
}

else version (freebsd)
    import tango.stdc.posix.unistd : readlink;

else version (linux)
    import tango.stdc.posix.unistd : readlink;

else version (Windows)
{
    import tango.sys.win32.UserGdi : GetModuleFileNameA, MAX_PATH;
    import tango.text.convert.Utf : toString;
    import tango.text.Util : locate;
}

/**
 * Gets the path of the current process.
 * 
 * To fit the whole path inside the given buffer without
 * using the heap the buffer has to be equal or larger than:
 * 
 * On darwin: 1024
 * On freebsd: 1024
 * On linux: 1024
 * On windows: tango.sys.win32.UserGdi.MAX_PATH + 1
 * 
 * Params:
 *     buf = this buffer will be used unless it's to small
 *     
 * Returns: the path of the current process
 */
char[] getProcessPath (char[] buf = null)
{
    version (darwin)
    {
        uint size;
        
        _NSGetExecutablePath(null, &size); // get the length of the path
        
        if (size > buf.length)
            buf ~= new char[size - buf.length];
        
        _NSGetExecutablePath(buf.ptr, &size);
        
        auto tmp = buf[0 .. size];
        size_t len = 1024 - size;   
        buf = buf[size .. $];
        
        if (len > buf.length)
            buf ~= new char[len - buf.length];

        auto strLen = strlenz(realpath(tmp.ptr, buf.ptr));
        buf = buf[0 .. strLen];;
    }
    
    else version (freebsd)
    {
        const size_t len = 1024;
        
        if (len > buf.length)
            buf ~= new char[len - buf.length];
        
        auto count = readlink("/proc/curproc/file".ptr, buf.ptr, buf.length);
        
        buf = buf[0 .. count];
    }
    
    else version (linux)
    {
        const size_t len = 1024;
        
        if (len > buf.length)
            buf ~= new char[len - buf.length];
        
        auto count = readlink("/proc/self/exe".ptr, buf.ptr, buf.length);
        
        buf = buf[0 .. count];
    }
    
    else version (Windows)
    {
        const size_t len = MAX_PATH + 1; // Don't forget the null char
        
        if (len > buf.length)
            buf ~= new char[len - buf.length];
        
        GetModuleFileNameA(null, buf.ptr, buf.length - 1);
        
        size_t i = buf.locate(char.init);
        
        buf = buf[0 .. i - 1]; // Remove the null char      
    }
    
    else
        assert(false, "getProcessPath is not supported on this platform");

    return buf;
}